a7f49a2585
* rename swig files .i in .swig * update constraint_solver and routing * backport math_opt changes * move dynamic loading to ortools/third_party_solvers
56 lines
2.2 KiB
CMake
56 lines
2.2 KiB
CMake
# Copyright 2010-2025 Google LLC
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
set_property(SOURCE routing.swig PROPERTY CPLUSPLUS ON)
|
|
set_property(SOURCE routing.swig PROPERTY SWIG_MODULE_NAME pywrapcp)
|
|
set_property(SOURCE routing.swig PROPERTY COMPILE_DEFINITIONS
|
|
${OR_TOOLS_COMPILE_DEFINITIONS} ABSL_MUST_USE_RESULT=)
|
|
set_property(SOURCE routing.swig PROPERTY COMPILE_OPTIONS -nofastunpack)
|
|
swig_add_library(pywrapcp
|
|
TYPE MODULE
|
|
LANGUAGE python
|
|
OUTPUT_DIR ${PYTHON_PROJECT_DIR}/constraint_solver
|
|
SOURCES routing.swig)
|
|
|
|
target_include_directories(pywrapcp PRIVATE ${Python3_INCLUDE_DIRS})
|
|
set_property(TARGET pywrapcp PROPERTY SWIG_USE_TARGET_INCLUDE_DIRECTORIES ON)
|
|
target_compile_definitions(pywrapcp PUBLIC "PY3")
|
|
|
|
# note: macOS is APPLE and also UNIX !
|
|
if(APPLE)
|
|
set_target_properties(pywrapcp PROPERTIES
|
|
SUFFIX ".so"
|
|
INSTALL_RPATH "@loader_path;@loader_path/../../${PROJECT_NAME}/.libs")
|
|
target_link_options(pywrapcp PRIVATE "LINKER:-undefined,dynamic_lookup")
|
|
elseif(UNIX)
|
|
set_target_properties(pywrapcp PROPERTIES
|
|
INSTALL_RPATH "$ORIGIN:$ORIGIN/../../${PROJECT_NAME}/.libs")
|
|
endif()
|
|
target_link_libraries(pywrapcp PRIVATE ortools::ortools)
|
|
|
|
# Variable PYTHON_LIBRARIES can contains keyword `optimized`
|
|
# which won't be interpreted inside a generator expression.
|
|
# i.e. we can't use: $<$<PLATFORM_ID:Windows>:${PYTHON_LIBRARIES}>
|
|
# see: https://cmake.org/cmake/help/git-stage/command/target_link_libraries.html#command:target_link_libraries
|
|
if(MSVC)
|
|
target_link_libraries(pywrapcp PRIVATE ${Python3_LIBRARIES})
|
|
endif()
|
|
|
|
# Test
|
|
if(BUILD_TESTING)
|
|
file(GLOB PYTHON_SRCS "*_test.py")
|
|
foreach(FILE_NAME IN LISTS PYTHON_SRCS)
|
|
add_python_test(FILE_NAME ${FILE_NAME})
|
|
endforeach()
|
|
endif()
|